5 GOSUB60000: REM TABELLEN BESTIMMEN
10 REM ********* STEUERUNG ***********
30 GOSUB50000
40 REM REAGIEREN-AUFRUFEN
60 REM ******* DEMONSTRATION *********
62 PRINT:PRINT"BE$ = ";BE$:PRINT
64 PRINT"VERBZAHL (VE) =";VE
66 PRINT"1.GEGENSTANDSZAHL (G1) =";G1
68 PRINT"2.GEGENSTANDSZAHL (G2) =";G2
70 PRINT"OBJEKTZAHL (OB) =";OB
72 PRINT"PERSONENZAHL (PE) =";PE
80 GOTO10
90 REM *******************************
50000 REM BEFEHL BE$ VOM SPIELER ERFRAGEN --------------------------------------
50010 IFUD=1THEN52000
50020 INPUT"WAS NUN ";BE$
50030 GOTO51000
51000 REM BE$ IN BE$(1)-BE$(10) ZERLEGEN----------------------------------------
51010 FORI=1TO10:BE$(I)="":NEXT
51020 WZ=1
51030 FORI=1TOLEN(BE$)
51040 :IFMID$(BE$,I,1)=" "THENGOSUB51100:GOTO51060
51045 :IFWZ>10THENPRINT"EINGABE IST ZU LANG !":I=LEN(BE$)+1:GOTO51060
51050 :BE$(WZ)=BE$(WZ)+MID$(BE$,I,1)
51060 NEXTI
51070 GOTO52000
51100 REM AU$ WOERTER AUSSORTIEREN
51110 IC=0:FORI1=1TOAZ
51120 :IFBE$(WZ)=AU$(I1)THENIC=1
51130 NEXTI1
51140 IFIC=0THENWZ=WZ+1:RETURN
51150 BE$(WZ)="":RETURN
52000 REM DIE BEFEHLSWOERTER UNTERSUCHEN UND DARAUS EINEN SINN DEUTEN ----------
52005 IFUD=1THENUD=0:GOTO52020
52010 WZ=1:VE=0:OB=0:PE=0
52020 IC=0:G1=0:G2=0
52025 REM *** VERB VE SUCHEN
52030 FORI=1TOVZ
52040 :IFBE$(WZ)=VE$(I)THENVE=I:IC=1
52050 NEXTI:IFIC=1THEN52150
52060 REM *** GEGENSTAND G1/G2 SUCHEN
52070 FORI=1TOGZ
52080 :IFBE$(WZ)<>GE$(I)THEN52090
52082 : IC=1
52084 : IFG1=0THENG1=I
52086 : G2=I:IFG2=G1THENG2=0
52090 NEXTI:IFIC=1THEN52150
52100 REM *** OBJEKT OB SUCHEN
52110 FORI=1TOOZ
52120 :IFBE$(WZ)=OB$(I)THENOB=I:IC=1
52130 NEXTI:IFIC=1THEN52150
52132 REM *** PERSON PE SUCHEN
52133 FORI=1TOPZ
52134 :IFBE$(WZ)=PE$(I)THENPE=I:IC=1
52135 NEXTI:IFIC=1THEN52150
52137 IFBE$(WZ)="UND"THENUD=1:IC=1
52140 IFIC=0THENPRINT"ICH KENNE ";BE$(WZ);" NICHT !":RETURN
52150 WZ=WZ+1
52160 IFWZ>10ORBE$(WZ)=""ORUD=1THENRETURN
52170 IC=0:GOTO52025
60000 REM *****************************
60001 REM * W O R T - T A B E L L E N *
60002 REM *****************************
60010 REM *** AU$-WORT-TABELLE
60020 DATA DER,DIE,DAS,DEN, ,UEBER,UNTER,AUF,IN,VON,VOM,IM,NACH,DURCH,MIT,DEM
60022 DATA AM
60030 AZ=17:DIMAU$(AZ):FORI=1TOAZ:READAU$(I):NEXT
60050 REM *** VERB-TABELLE VE$
60060 DATA NIMM,VERLIERE,OEFFNE,GIB,SAGE,INVENTUR,BEFESTIGE
60070 VZ=7:DIMVE$(VZ):FORI=1TOVZ:READVE$(I):NEXT
60090 REM *** GEGENSTANDS-TABELLE GE$
60100 DATA SCHWERT,SCHLUESSEL,SEIL,FACKEL,ARMBRUST,HELM,SCHILD
60110 GZ=7:DIMGE$(7):FORI=1TOGZ:READGE$(I):NEXT
60130 REM *** OBJEKT-TABELLE OB$
60140 DATA FENSTER,TUER,TRUHE,KISTE,FALLTUER
60150 OZ=5:DIMOB$(OZ):FORI=1TOOZ:READOB$(I):NEXT
60160 REM *** PERSONEN-TABELLE PE$
60170 DATA GEIST,MONSTER,THORIN,GOMMEL,ORK
60180 PZ=5:DIMPE$(PZ):FORI=1TOPZ:READPE$(I):NEXT
60200 RETURN